Stickfunction

Reads axis position from attached gaming devices

User Input Functions (Graphics Library)functiondocumented

Syntax

Declare Function Stick ( ByVal axis As Long ) As Long

Parameters

Name		Description
`axis`		the axis number to query for position

Return value

Returns a number between 1 and 200 for specified axis, otherwise zero (0), if the device is not attached.

Description

Stick will retrieve the axis position for the first and second axes on the first and second gaming devices. axis must be a number between 0 and 3 having the following meaning:

Axis	Returns
0	X position of gaming device A
1	Y position of gaming device A when STICK(0) was called
2	X position of gaming device B when STICK(0) was called
3	Y position of gaming device B when STICK(0) was called

Stick(0) must first be called to obtain the positions for the other axes.

Remarks

Usage



result = Stick( axis )

Dialect Differences

Only available in the -lang qb dialect.

Differences from QB

None

Example

'' Compile with -lang qb



'$lang: "qb"



Screen 12



Do

    Locate 1, 1

    Print "Joystick A-X position : "; Stick(0); "   "

    Print "Joystick A-Y position : "; Stick(1); "   "

    Print "Joystick B-X position : "; Stick(2); "   "

    Print "Joystick B-Y position : "; Stick(3); "   "

    Print

    Print "Button A1 was pressed : "; Strig(0); "  "

    Print "Button A1 is pressed  : "; Strig(1); "  "

    Print "Button B1 was pressed : "; Strig(2); "  "

    Print "Button B1 is pressed  : "; Strig(3); "  "

    Print "Button A2 was pressed : "; Strig(4); "  "

    Print "Button A2 is pressed  : "; Strig(5); "  "

    Print "Button B2 was pressed : "; Strig(6); "  "

    Print "Button B2 is pressed  : "; Strig(7); "  "

    Print

    Print "Press ESC to Quit"



    If Inkey$ = Chr$(27) Then

        Exit Do

    End If



    Sleep 1



Loop

Reference

Documented in KeyPgStick.html